ຟັງຊັນ TypeName; ຟັງຊັນ VarType

ສົ່ງຄືນຂໍ້ຄວາມ ຫຼື ຄ່າຕົວເລກທີ່ມີຂໍ້ມູນປະເພດຂອງຕົວປ່ຽນ.

ໄວຍາກອນ:


  TypeName (Varname As Variant) As String
  VarType (Varname As Variant) As Integer

ປະເພດຄ່າທີ່ສົ່ງກັບ:

ຂໍ້ຄວາມສຳລັບ TypeName ໂດຍຈະມີ '()' ຕໍ່ທ້າຍສຳລັບອາເຣ.
ຈຳນວນຖ້ວນສຳລັບ VarType. ຕົວເລກ 8192 ຈະຖືກບວກເຂົ້າກັບຄ່າທີ່ສົ່ງຄືນສຳລັບອາເຣໃນ VarType.

ພາຣາມິເຕີ:

Varname: ຊື່ຕົວປ່ຽນທີ່ທ່ານຕ້ອງການກວດສອບປະເພດ.

ຄ່າຕໍ່ໄປນີ້ແມ່ນຈະຖືກສົ່ງຄືນ:

ຄ່າ TypeName	ຄ່າຄົງທີ່ ທີ່ມີຊື່	VarType values	ປະເພດຕົວປ່ຽນ
…()		8192	ອາເຣ ຂອງຕົວປ່ຽນ
Boolean		11	ຕົວປ່ຽນ Boolean
Byte		17	ຕົວປ່ຽນ Byte
Date	V_DATE	7	ຕົວປ່ຽນ Date (ວັນທີ)
Currency	V_CURRENCY	6	ຕົວປ່ຽນ Currency (ເງິນຕາ)
Double	V_DOUBLE	5	ຕົວປ່ຽນເລກເສດຄວາມລະອຽດສອງເທົ່າ (Double-precision)
Error		11	ຕົວປ່ຽນປະເພດຂໍ້ຜິດພາດ (Error type)
Integer	V_INTEGER	2	ຕົວປ່ຽນ Integer (ເລກຖ້ວນ)
Long	V_LONG	3	ຕົວປ່ຽນເລກຖ້ວນຍາວ Long
Object		9	ຕົວປ່ຽນ Object (ວັດຖຸ)
Single	V_SINGLE	4	ຕົວປ່ຽນເລກເສດຄວາມລະອຽດດ່ຽວ (Single-precision)
String	V_STRING	8	ຕົວປ່ຽນ String (ຂໍ້ຄວາມ)
Variant		12	ຕົວປ່ຽນ Variant (ສາມາດບັນຈຸທຸກປະເພດທີ່ກຳນົດໂດຍການນິຍາມ)
Empty	V_EMPTY	0	ຕົວປ່ຽນ Variant ທີ່ຍັງບໍ່ທັນໄດ້ກຳນົດຄ່າເລີ່ມຕົ້ນ
Null	V_NULL	1	ບໍ່ມີຂໍ້ມູນທີ່ຖືກຕ້ອງ

ລະຫັດຂໍ້ຜິດພາດ:

5 ການເອີ້ນໃຊ້ໂປຣຊີເຈີບໍ່ຖືກຕ້ອງ

ຕົວຢ່າງ:


  Sub TypeName_VarType_example
    Const __Object=9, __Error=10, __Boolean=11, __Variant=12, __Byte=17, _
      __Array = 8192, aText = "Lorem ipsum dolor sit amet, consectetur …"
    Dim int16 As Integer,  int32() As Long   ' V_INTEGER,  V_LONG
    Dim flt32!,            flt64() As Double ' V_SINGLE,   V_DOUBLE
    Dim curr@,             dat3 As Date      ' V_CURRENCY, V_DATE
    Dim strng() As String, objct() As Object ' V_STRING,   …
    Dim bool As Boolean,   unkwn(), byt3 As Byte ' …,      V_EMPTY, …
    Dim table(-3 To 5)
    MsgBox _
     TypeName(int16) &" "& Vartype(int16) &" "& V_INTEGER        &" "& Chr(13) &_
     TypeName(int32) &" "& Vartype(int32) &" "& V_LONG+__Array   &" "& Chr(13) &_
     TypeName(flt32) &" "& VarType(flt32) &" "& V_SINGLE         &" "& Chr(13) &_
     TypeName(flt64) &" "& VarType(flt64) &" "& V_DOUBLE+__Array &" "& Chr(13) &_
     TypeName(dat3)  &" "& VarType(dat3)  &" "& V_DATE           &" "& Chr(13) &_
     TypeName(curr)  &" "& VarType(curr)  &" "& V_CURRENCY       &" "& Chr(13) &_
     TypeName(atext) &" "& VarType(aText) &" "& V_STRING         &" "& Chr(13) &_
     TypeName(strng) &" "& VarType(strng) &" "& V_STRING+__Array &" "& Chr(13) &_
     TypeName(objct) &" "& VarType(objct) &" "& __Object+__Array &" "& Chr(13) &_
     TypeName(unkwn) &" "& VarType(unkwn) &" "& V_EMPTY          &" "& Chr(13) &_
     TypeName(bool)  &" "& VarType(bool)  &" "& __Boolean        &" "& Chr(13) &_
     TypeName(varnt) &" "& VarType(varnt) &" "& V_EMPTY          &" "& Chr(13) &_
     TypeName(table) &" "& VarType(table) &" "&__Variant+__Array &" "& Chr(13) &_
     TypeName(byt3)  &" "& VarType(byt3)  &" "& __Byte           _
     ,, "ປະເພດຂໍ້ມູນໃນ LibreOffice Basic"
    Msgbox "TypeName(table): "&TypeName(table) &Chr(13)& _
      "VarType(table)="&Vartype(table) _
      ,,"Array ຂອງຄ່າ Variant"
  End Sub ' TypeName_VarType_example

ຄຳສັ່ງ Const

ຄຳສັ່ງ Dim

ຟັງຊັນ MsgBox